Subscribe
Before a creature trying accepting something when the person asked is occupied:
let N be the carrying capacity of the person asked;
let N be N minus 1;
if the number of things carried by the person asked is greater than N
begin;
try the person asked trying dropping a random thing carried by the person asked;
end if.
The days of play-testing are harrowing. The first thing to do is to get a few “friends” and make them play for a while. Look over their shoulders, scribble furiously on a piece of paper, moan with despair and frustration, but do not speak. Force yourself not to explain or defend, whatever the provocation. Expect to have abuse heaped on you, and bear up nobly under the strain. To quote Dave Lebling (on testing ‘Suspect’, from an article in the “New Zork Times”):Many games don't get this kind of playtesting, or else you're the playtester.> BARTENDER, GIVE ME A DRINK
“Sorry, I’ve been hired to mix drinks and that’s all.”
« Older SNES OC'd... | Today... Newer »
This thread has been archived and is closed to new comments
"Bogart"
The Trailer is a room. "A full-length mirror is the main amenity in here, and that suits you just fine." The full-length mirror is scenery in the Trailer. Instead of examining the mirror, try taking inventory.
The player wears a fedora, a jacket, a shirt, some undershorts, an undershirt, some slacks, a pair of socks, and a pair of shoes.
Underlying relates one thing to various things. The verb to underlie (it underlies, they underlie, it is underlying, it is underlaid) implies the underlying relation. The verb to be under implies the underlying relation.
The shirt underlies the jacket. The pair of socks underlies the pair of shoes. The undershorts underlie the slacks. The undershirt underlies the shirt.
Check taking off:
if the noun underlies something (called the impediment) which is worn by the player, say "[The impediment] is in the way." instead.
Carry out taking off:
now the noun is not underlaid by anything.
After taking off something:
say "You are now wearing[list of uppermost things worn by the player]."
Overlying relates one thing to various things. The verb to overlie (it overlies, they overlie, it is overlying) implies the overlying relation.
The jacket overlies the shirt. The shoes overlie the socks. The slacks overlie the undershorts. The shirt overlies the undershirt.
Before wearing something when something (called the impediment) which overlies the noun is worn by the player:
say "(first removing [the impediment])[line break]";
silently try taking off the impediment;
if the player is wearing the impediment, stop the action.
Before taking off something which underlies something (called the impediment) which is worn by the player:
say "(first removing [the impediment])[line break]";
silently try taking off the impediment;
if the noun underlies something which is worn by the player, stop the action.
Carry out wearing:
if the noun overlies something (called the hidden item) worn by the player, now the hidden item underlies the noun.
Instead of looking under something which is worn by the player:
if something (called the underwear) underlies the noun, say "You peek at [the underwear]. Yup, still there.";
otherwise say "Just you in there."
Instead of taking inventory:
say "You're carrying[list of things carried by the player][if the player wears something]. You are wearing[list of uppermost things worn by the player][end if]."
Definition: a thing is uppermost if it is not under something.
posted by zabuni at 8:08 PM on April 30, 2006